first

01_3D-Druck/openscad/action-stein.scad

@@ -0,0 +1,42 @@
+// Action-Stein: Szenario-Traeger mit aufrechtem Kartenschlitz
+// SLC-Workshop Tabletop · Einheiten: mm
+
+/* [Fuss] */
+foot_d      = 49;    // sitzt in Verankerung (Ø50)
+foot_h      = 5;
+stand_ring  = 70;    // optionaler Standring fuer Kippstabilitaet
+use_ring    = true;
+
+/* [Koerper] */
+body_d      = 35;
+body_h      = 30;
+
+/* [Kartenschlitz] */
+card_w      = 74;    // fuer Karte 70 mm breit
+card_t      = 4;     // Schlitzdicke
+card_h      = 25;    // Einstecktiefe
+
+/* [Gewichtseinlage M8] */
+nut_af      = 13;    // Schluesselweite M8-Mutter
+nut_h       = 6.5;
+$fn = 96;
+
+module base() {
+    if (use_ring)
+        cylinder(d = stand_ring, h = 2);
+    translate([0,0,0]) cylinder(d = foot_d, h = foot_h);
+}
+
+module body() {
+    translate([0,0,foot_h]) cylinder(d = body_d, h = body_h);
+}
+
+difference() {
+    union() { base(); body(); }
+    // Kartenschlitz (zentriert in X, durch den Koerperkopf)
+    translate([-card_w/2, -card_t/2, foot_h + body_h - card_h])
+        cube([card_w, card_t, card_h + 1]);
+    // Gewichtsaussparung im Fuss (Sechskant fuer M8-Mutter)
+    translate([0, 0, -0.1])
+        cylinder(d = nut_af / cos(30), h = nut_h, $fn = 6);
+}